solidity v8.0新增特性

solidity v8.0新增特性，建议完整学了基础之后再来看本文。

1. 安全数学

也就是说从v8.0后，不再需要使用第三方SafeMath库，默认运算时，若溢出，会检测结果并报错。

// SPDX-License-Identifier: MIT
pragma solidity ^0.8;

contract SafeMath{
    //负数时，会返回报错：call to SafeMath.testUnderflow errored: VM error: revert.
    function testUnderflow() public pure returns(uint){
        uint x=0;
        x--;
        return x;
    }

    //负数时，会返回uint的最大值
    function testUncheckedUnderflow() public pure returns(uint){
        uint x=0;
        unchecked { x--; }
        return x;
    }
}

2. 自定义错误

// SPDX-License-Identifier: MIT
pragma solidity ^0.8;

contract VendingMachine{
    address payable owner = payable(msg.sender);
    //原先使用方式，通过字符串返回错误信息，字符串越长，gas消耗越大
    function withdraw() public {
        if (msg.sender != owner){
            revert("error");
        }
        owner.transfer(address(this).balance);
    }

    //通过方法定义error，当遇到异常，可以详细的抛出异常位置，参数等信息
    error Unauthorized(address caller);
    function withdraw2() public {
        if (msg.sender != owner){
            revert Unauthorized(msg.sender);
        }
        owner.transfer(address(this).balance);
    }
}

3. 函数在合约之外

// SPDX-License-Identifier: MIT
pragma solidity ^0.8;

function helper(uint x) pure returns (uint){
        return x * 2;
}

contract TestHelper {
    function test() external pure returns (uint){
        return helper(123);
    }
}

4. 引用合约并起别名

很多语言中都有该特性

// SPDX-License-Identifier: MIT
pragma solidity ^0.8;
import { Unauthorized, helper as h1} from "./Sol.sol";

function helper(uint x) pure returns (uint){
        return x * 2;
}

contract Import {}

5. create2

通过salt来获取合约地址，只要使用salt和new就会自动使用create2地址，具体细节，可以看solidity入门教程中的讲解

// SPDX-License-Identifier: MIT
pragma solidity ^0.8;

contract D{
    uint public x;
    constructor(uint a) {
        x = a;
    }
}

contract Create2{
    // 1. 先通过getBytes32获取salt
    function getBytes32(uint salt) external pure returns (bytes32){
        return bytes32(salt);
    }

    // 2. 通过getAddress传入salt 和 参数，得到D合约的地址
    function getAddress(bytes32 salt, uint arg) external view returns (address){
        address addr = address(uint160(uint(keccak256(abi.encodePacked(
            bytes1(0xff),
            address(this),
            salt,
            keccak256(abi.encodePacked(
                type(D).creationCode,
                arg
            ))
        )))));
        return addr;
    }

    //通过发布合约获取
    address public deployedAddr;

    // 3. 正常发布合约方式获取合约地址，该地址与getAddress得到的地址是一样的
    // 4. 也就是说，新版这里，只要使用salt和new就会自动使用create2地址
    function createDSalted(bytes32 salt,uint arg) public {
        D d = new D{salt:salt}(arg);
        deployedAddr = address(d);
    }
}

6. 总结

本文编辑完毕

Donate